Практическое руководство. Чтение текстовых файлов различных форматов в Visual Basic

Статья
11/05/2008

Обновлен: Ноябрь 2007

Объект TextFieldParser позволяет легко и эффективно анализировать структурированные текстовые файлы, например файлы журналов. Обработать файл, имеющий содержимое в нескольких форматах, можно с помощью метода PeekChars, который позволяет определять формат каждой анализируемой строки на протяжении всего файла.

Анализ текстового файла с содержимым в нескольких форматах

Определите ожидаемый формат и формат, используемый при сообщении об ошибке.
```
Dim StdFormat As Integer()= {5,10,11,-1}
Dim ErrorFormat As Integer() = {5,5,-1}
```

Создайте новый объект TextFieldParser, определив ширину и формат.

Using MyReader As New _
Microsoft.VisualBasic.FileIO.TextFieldParser("C:\testfile.txt")
MyReader.TextFieldType = FileIO.FieldType.FixedWidth

Переберите в цикле строки, проверяя формат перед чтением.

Dim CurrentRow As String()
While Not MyReader.EndOfData
   Try
      Dim RowType As String = MyReader.PeekChars(3)
      If String.Compare(RowType, "Err") = 0 Then
         ' If this line describes an error, the format of 
         ' the row will be different.
         MyReader.SetFieldWidths(ErrorFormat)
         CurrentRow = MyReader.ReadFields
         MyReader.SetFieldWidths(StdFormat)
                    Else
         'Otherwise parse the fields normally
         CurrentRow = MyReader.ReadFields
         For Each newString As String In CurrentRow
            My.Computer.FileSystem.WriteAllText _
            ("newFile.txt", newString, True)
          Next
   End If

Выведите сообщения об ошибках на консоль.

      Catch ex As _
      Microsoft.VisualBasic.FileIO.MalformedLineException
         MsgBox("Line " & ex.Message & " is invalid.")
      End Try
   End While
End Using

Пример

В этом примере производится чтение данных из файла testfile.txt.

Dim StdFormat As Integer() = {5, 10, 11, -1}
Dim ErrorFormat As Integer() = {5, 5, -1}
Using MyReader As New _
Microsoft.VisualBasic.FileIO.TextFieldParser("C:\testfile.txt")
   MyReader.TextFieldType = FileIO.FieldType.FixedWidth
   MyReader.FieldWidths = StdFormat
   Dim CurrentRow As String()
      While Not MyReader.EndOfData
         Try
            Dim RowType As String = MyReader.PeekChars(3)
            If String.Compare(RowType, "Err") = 0 Then
               ' If this line describes an error, the format of the row will be different.
               MyReader.SetFieldWidths(ErrorFormat)
               CurrentRow = MyReader.ReadFields
               MyReader.SetFieldWidths(StdFormat)
            Else
               ' Otherwise parse the fields normally
               CurrentRow = MyReader.ReadFields
               For Each newString As String In CurrentRow
                  My.Computer.FileSystem.WriteAllText("newFile.txt", newString, True)
               Next
            End If
         Catch ex As Microsoft.VisualBasic.FileIO.MalformedLineException
            MsgBox("Line " & ex.Message & " is invalid.  Skipping")
         End Try
      End While
End Using

Отказоустойчивость

Возникновение исключения возможно при следующих условиях:

Строка не может быть проанализирована с использованием указанного формата (MalformedLineException). Сообщение исключения указывает строку, вызвавшую исключение, а в Свойство TextFieldParser.ErrorLine находится текст, содержащийся в строке.
Заданный файл не существует (FileNotFoundException).
Ситуация частичного доверия, в которой пользователь не имеет достаточных разрешений для доступа к файлу. (SecurityException).
Путь слишком длинный (PathTooLongException).
Пользователь не имеет необходимых разрешений для доступа к файлу (UnauthorizedAccessException).

См. также

Share via

Практическое руководство. Чтение текстовых файлов различных форматов в Visual Basic

Анализ текстового файла с содержимым в нескольких форматах

Пример

Отказоустойчивость

См. также

Задачи

Основные понятия

Ссылки

Дополнительные ресурсы